Tick Fade Indicator for Think or Swim

Here is a Thinkscript indicator that plots a dot if the NYSE TICK for the current chart timeframe breaches a threshold value. Compare the chart below to see what I mean:

I plotted the Tick Fade indicator on both charts, so the bottom chart is comparing the TICK to itself. With this indicator, if you set up a chart for 5 minutes, then you will get a paintbar if the high NYSE tick on a 5 min bar is over the threshold value (default 1000). Similar for a low tick. The timeframes are linked in this study, so the primary timeframe for the chart will dictate the corresponding timeframe for “high”, “low” etc. for the TICK reference.

I call this the Tick Fade indicator because I want to fade an extreme move in the TICK, as an indication that too many stocks are all moving in the same direction. If I’m in a trade, and I get a high TICK reading in my direction, I want to take some profit, as this is likely to be close to the final extreme of the move. In Mastering the Trade, John Carter uses extreme TICK readings that are adverse to his position as a signal to get out, which is not a fade, but an anticipation of more strength to come. Richard at Move the Markets has a lot of good articles about the TICK and its use. Many different strategies, but now you know how to use the TICK info without having to keep a seperate chart of the TICK open on your layout.

Here is the code:

# Tick Fade Indicator
# By Prospectus @ http://readtheprospectus.wordpress.com
#
# This indicator paints a dot if the NYSE tick for the
# current chart timeperiod breaches a threshold value.
#
def na=double.nan;
#
# Define how you want the value plotted. I chose 30% of
# bar range, plotted that distance above the high/low:
#
def range = high - low;
def plotter=range*0.3;
#
# Input the threshold values you are watching:
#
Input uThreshold=1000;
Input lThreshold=-1000;
#
# Now reference the high / low of corresponding bar
# for the NYSE tick:
#
def hi = high("$TICK");
def lo = low("$TICK");
#
# Define the plots:
#
plot lowtick=if lo<=lThreshold then low-plotter else na;
plot hightick=if hi>=uThreshold then high+plotter else na;
#
# Formatting:
#
lowtick.setdefaultcolor(color.yellow);
lowtick.setstyle(curve.points);
lowtick.setlineweight(4);
hightick.setdefaultcolor(color.yellow);
hightick.setstyle(curve.points);
hightick.setlineweight(4);

Tags: reference_symbol, Thinkscript, TICK, tick_fade